Temat lekcji: Ułamki zwykłe, ułamki dziesiętne, ułamki okresowe.

Cele lekcji:
-sposoby skracania ułamków, zastosowanie nwd,
-zamiana ułamka zwykłego na dziesiętny,
-sposoby wydzielania okresów,
-wyznaczanie ilości cyfr między przecinkiem a okresem,
-wyznaczanie długości okresu.

Przebieg lekcji:

  1. Omówienie sposobów wyznaczania największego wspólnego dzielnika (największy wspólny dzielnik będzie potrzebny w pkt. d do skracania ułamków):
  2. a) Sposób wyznaczania najwiekszego wspólnego dzielnika z wykorzystaniem standardowej procedury gcd kalkulatora TI 92, np. wpisujemy w linii edycyjnej wyrażenie gcd(1995,1957) i po naciśnięciu ENTER otrzymujemy wynik 19.

    b) Sposób wyznaczania najwiekszego wspólnego dzielnika przy pomocy algorytmu Euklidesa zapisanego jako program na kalkulator TI 92. Pisanie programu rozpoczynamy klawiszami APPS - 7:Program Editor -Enter - 3:New - Enter i w okienku Variable wpisujemy nazwę programu, np. algorytm i naciskamy dwa razy ENTER.

    :algorytm(a,b)
    :Prgm
    :ClrIO
    :1->r
    :While r>0
    : mod(a,b)->r
    :
    Disp string(a)&"="&string(intDiv(a,b))&"*"&string(b)&"+"&string(r)
    : b->a
    : r->b
    :EndWhile
    :Disp "NWD="&string(a)
    :EndPrgm

    Po napisaniu programu należy przejść klawiszami APPS i 1:Home do głównego okna kalkulatora i w linii edycyjnej wpisać zlecenie: algorytm(1995,1957). Po naciśnięciu ENTER otrzymujemy wynik:

    1995=1*1957+38
    1957=51*38+19
    38=2*19+0
    NWD=19

    c) Ćwiczenia w wyznaczaniu najwiekszego wspólnego dzielnika różnych par liczb,

    d) Ułożenie programu na skracanie ułamków z wykorzystaniem najwiekszego wspólnego dzielnika:

    :skroc(l,m)
    :Prgm
    :ClrIO
    :string(l)&"/"&string(m)&"="->s
    :gcd(l,m)->n
    :l/n->l
    :m/n->m
    :Disp s&string(l)&"/"&string(m)
    :EndPrgm

    Przykładowy wynik działania programu - w linii edycyjnej należy wpisać zlecenie skroc(1995,1957)

    1995/1957=105/103

    e) Ćwiczenia w skracaniu ułamków.

  3. Sposoby zamiany ułamka zwykłego na ułamek dziesiętny:
  4. a) Sposób poprzez zwykłe pisemne dzielenie:
    1. 133 : 74 = 1,7972972972972972972...
      74
      590
      518
      720
      666
      540
      518
      220
      148
      720
      ...

    Wniosek: Jeśli w trakcie dzielenia powtórzy się któraś reszta to dzielenie można przerwać ponieważ dalsze cyfry rozwinięcia dziesiętnego również będą się powtarzać.

    b) Sposób zamiany ułamka zwykłego na dziesiętny do 12 cyfr znaczących - wykorzystanie opcji APPROXIMATE i Display Digits-FLOAT 12 kalkulatora TI 92:

    133/74 1.7972972973

    Należy zwrócić uwagę, że ostatnia cyfra tego rozwinięcia jest zaokrąglana.

    c) Sposób zamiany ułamka zwykłego na dziesiętny do 175 miejsc po przecinku przy pomocy poniższego programu:

    :dziel(licz,mian)
    :Prgm
    :ClrIO
    :string(licz)&"/"&string(mian)&"="&string(intDiv(licz,mian))&"." ->s
    :For n,1,175,1
    : mod(licz,mian)*10->licz
    : s&string(intDiv(licz,mian)) ->s
    : If mod(n,25)=0 Then
    : Disp s
    : " "->s
    : EndIf
    :EndFor
    :Disp s
    :EndPrgm

    Przykładowy wynik działania programu - w linii edycyjnej należy wpisać zlecenie: dziel(133,74)

    133/74= 1.7972972972972972972972972
    9729729729729729729729729
    7297297297297297297297297
    2972972972972972972972972
    9729729729729729729729729
    7297297297297297297297297
    2972972972972972972972972

  5. Własności ułamków okresowych.
  1. Ćwiczenia w zamianie ułamków zwykłych na dziesiętne przy pomocy programu dziel(a,b) i wyznaczanie ich okresów:
  2. 2 / 3 = 0.6666666666666666666666666 - okresem jest cyfra 6
    3 / 4 = 0.7500000000000000000000000 - okresem jest cyfra 0
    3 / 5 = 0.6000000000000000000000000 - okresem jest cyfra 0
    5 / 6 = 0.8333333333333333333333333 - okresem jest cyfra 3
    6 / 7 = 0.8571428571428571428571428 - okresem jest grupa cyfr 857142
    9 / 11 = 0.818181818181818181818181 - okresem jest grupa cyfr 81
    11 / 15 = 0.733333333333333333333333 - okresem jest cyfra 3
    19 / 60 = 0.316666666666666666666666 - okresem jest cyfra 6
    133 / 74 =1.7972972972972972972972972 - okresem jest grupa cyfr 972,
  3. Należy zwrócić uwagę, że dla wiekszych liczb wyznaczanie okresów jest dość kłopotliwe i dlatego należy poszerzyć program dziel(a,b) o procedurę ich automatycznego wyznaczania. Poniższy program na zamianę ułamków zwykłych na okresowe zawiera taką procedurę.

:zuzno(licz,mian)
:Prgm
:ClrIO
:string(licz)&"/"&string(mian)&"="->s
:Disp s
:gcd(licz,mian)->nwd1
:licz/nwd1->licz
:mian/nwd1->mian
:"="&string(licz)&"/"&string(mian)&"="->s
:s&string(factor(licz))&"/("&string(factor(mian))&")="->s
:Disp s
:"="&string(intDiv(licz,mian))&"."->s
:mian->mian1
:0->i2
:While mod(mian1,2)=0
: i2+1->i2
: mian1/2->mian1
:EndWhile
:0->i5
:While mod(mian1,5)=0
: i5+1->i5
: mian1/5->mian1
:EndWhile
:max(i2,i5)->immpao
:If immpao=0
: s&"9"->s
:1->dlok
:9->licz1
:While mod(licz1,mian1)>0
: dlok+1->dlok
: mod(licz1,mian1)*10+9->licz1
:EndWhile
:For n,1,150,1
: mod(licz,mian)*10->licz
: s&string(intDiv(licz,mian))->s
: If immpao=n
: s&"("->s
: If immpao+dlok=n
: s&")"->s
: If mod(n,25)=0 Then
: Disp s
: " "->s
: EndIf
:EndFor
:Disp s
:EndPrgm

Po uruchomieniu tego programu zleceniem zuzno(1995,1957) otrzymujemy:

1995/1957=105/103=3*7*5/103=
=1.(0194174757281553398058252
427184466)0194174757281553
3980582524271844660194174
7572815533980582524271844
6601941747572815533980582
52019417475728155339805825

Program skraca ułamek, rozkłada licznik i mianownik na czynniki pierwsze i oznakowuje nawiasami ( ) okres.

c) Postawienie uczniom do rozwiązania problemu 1.

Problem 1. Czy każdy ułamek ma rozwinięcie okresowe?

Odpowiedź: Każdy ułamek zwykły ma rozwinięcie okresowe.

Uzasadnienie: W trakcie każdego dzielenia pisemnego któraś reszta musi się powtórzyć i dalsze cyfry rozwinięcia również będą się powtarzać. (Ilość różnych reszt ułamka nieskracalnego p/q, wynosi co najwyżej q-1.)

d) Sformułowanie i rozwiązanie problemu 2.

Problem 2. Czy zawsze okres rozpoczyna się tuż po przecinku? Jeśli nie, to jak określić ilość cyfr, rozwinięcia dziesiętnego ułamka, między przecinkiem a pierwszą cyfrą okresu?

W czasie rozwiązywania problemu uczniowie powinni wykonać wiele przykładów na zamianę ułamków zwykłych na okresowe i szczegółowo przeanalizować te przykłady w których okres nie rozpoczyna się tuż po przecinku. Program zuzno(a,b) podaje, oprócz rozwinięcia dziesiętnego i okresu, również rozkład licznika i mianownika na czynniki pierwsze, co powinno pomóc w rozwiązaniu problemu.

Odpowiedź: Ilość cyfr między przecinkiem a okresem równa jest większej z ilości dwójek lub piątek w rozkładzie mianownika na czynniki pierwsze.

Uzasadnienie: Każde dzielenie przez 2 lub przez 5 lub przez 2*5, czyli przez 10, daje jedną cyfrę rozwinięcia dziesiętnego. Cyfra ta nie powtarza się ponieważ takie dzielenie jest skończone i daje reszte zero. Jeśli w mianowniku są jeszcze inne czynniki różne od 2 i od 5 to dzielenie jest nieskończone i one decydują o okresie. Patrz przykłady 5/6, 11/15, 23/60, 133/74.

e) Sformułowanie i rozwiązanie problemu 3.

Problem 3. Jaka jest własność ułamków o mianownikach 9, 99, 999, ... ?

Uczniowie powinni wykonywać przykłady na zamianę ułamków o mianownikach 9, 99, 999, ... na ułamki okresowe i obserwować wyniki.

Odpowiedź: Ułamki o mianowniku 9, 99, 999, ... mają okresy złożone z tylu cyfr ile jest dziewiątek w mianowniku. Jednocześnie licznik takiego ułamka jest jego okresem (z ewentualnymi zerami na początku, jeśli ilość cyfr licznika jest mniejsza od ilości cyfr mianownika).

Np. 1/9 = 0.(1)11111111111111111111111111111...

5/9 = 0.(5)55555555555555555555555555555...

7/99 = 0.(07)0707070707070707070707070707...

12/99 = 0.(12)1212121212121212121212121212...

Odpowiedź jest prawidłowa nawet wtedy, gdy ułamek o mianowniku 9, 99, 999, ... skróci się, np. 6/9 = 2/3 = 0,(6)666666666666666666666666

592/999 = 16/27 = 0.(592)592592592592592592

f) Sformułowanie i rozwiązanie problemu 4.

Problem 4. Jak określić długość okresu ułamka p/q bez wykonywania dzielenia liczb p i q?

Pomysł rozwiązania tego problemu powinna nasunąć odpowiedź do poprzedniego problemu.

Odpowiedź: Dla ułamków o mianownikach 9, 99, 999,... długość okresu jest równa ilości dziewiątek w tych mianownikach. Zatem dla innych ułamków należy rozszerzyć je do mianownika 9 lub 99 lub 999 lub ... - ilość otrzymanych dziewiatek jest długością okresu.

Przykłady: a) ułamek o mianowniku 11 ma okres złożony z dwóch cyfr ponieważ można go rozszerzyć do ułamka o mianowniku 99.

b) ułamek o mianowniku 37 ma okres długości 3 ponieważ można go rozszerzyć do ułamka o mianowniku złożonym z 3 dziewiątek.

Sposób ten jest zastosowany w programie zuzno(a,b) do wyznaczania okresu.

g) Ćwiczenia w wyznaczaniu długości okresów ułamków. (przed rozszerzaniem ułamków dobrze jest rozłożyć na czynniki liczby 9, 99, 999, .... Wykorzystać do tego celu zlecenie factor(a), np. factor(999) 37*33.)

4. Zadanie domowe.

Znaleźć taką liczbę pierwszą q, aby ułamek 1999/q zapisany w postaci dziesiętnej miał w okresie:

a) 5 cyfr

b) 10 cyfr

c) 17 cyfr.